macro=;
  var:
 nulands
 equis
 yes 
 nombre 
 nodo
conf
 ;

/************************************************\
| This script export to TPS format the landmark   |
| coordinates of terminals and inner nodes of     |
| the first tree in memory. It produces one file  |
| for each lm configuration. Besides it generates |
| a tree drawing with the numbers of the inner    |
| nodes corresponding to the names given in the   |
| TPS file.                                       |        
\************************************************/


 if (ntrees < 0)
  sil-buf ; quote *You need to have some trees
            in memory ; proc/; end  


loop=char 0 lmnchar
 set nulands (lmnpoints [#char] +1) ; 
 set conf #char ; 
 log Config_'conf'.tps ;
 lquote [ ;
 taxn=;
 loop=nod 0 (2*ntax)
   sil-file ; quote LM='nulands' ;sil=all ;
   if ( #nod <= ntax )
        set nombre $$taxon(#nod) ;  
   else
        set nodo #nod ;  
   end
   loop=la 0 lmnpoints [#char] 	 
         set equis lmxcoord [#char #la 0 #nod] ;
         set yes   lmycoord [#char #la 0 #nod] ;
         sil-file ; quote &32 &32 &32 'equis' &32 &32 &32 'yes';sil=all ; 
    stop
    if ( #nod <= ntax )
      sil-file ; quote ID=$nombre ;sil=all ;   
    else
      sil-file ; quote ID=Internal_node_#nod ;sil=all ;   
    end 
 stop
 log/;
stop
log &tree.emf ;
nak- ;
tp ; 
log/& ;
proc/;