macro-; 
macro *10 3500 ; 
macro [ 1000 ; 
macro=; 

if ( ( ntax < 1 ) || !( isfile taggedtre.out ) )  

if ( !( isfile taggedtre.out ) )  
   quote ...; 
   quote OOOPS -- file taggedtre.out not found! ; 
   quote ...; 
else 
   quote ...; 
   quote OOOPS -- you have not read the data set! ; 
   quote ...; 
   end 

errmsg 
  this script processes results produced by the script 
  partbremers.run --it shows the bremer supports for 
  each group in the consensus, for each partition, in 
  a friendly way. 

  Before running this script, you have to run 
  partbremers.run, place all the resulting files in 
  the current folder, read the data set (make sure 
  you make space for long taxon names), and call 
  this script.; 
end  
  
goto = %0 ; 
clb ; 
warn - ; 
txts 1500 ; 
keep 0 ; 
p taggedtre.out ; 
lquote[ ; 
var : choice[(2*root+1)] blonu ins[400] outs[400] tmp[400] blonu treenu ; 

loop 1 1 

    set blonu 0 ; 
    loop root nnodes[0] set choice[#2] 0 ; stop 

    opendlg 20 20 420 220 Select ... ; 

	frame 20 30 180 80 Plot supports for all NODES ... ; 
	spin 0 nblocks blonu 30 50 170 22 BLOCK nr. ; 

	frame 220 30 180 80 Plot supports for all BLOCKS ... ; 
	spin 0 ntrees treenu 230 50 170 22 on tree nr. ; 
	nodsel choice 230 80 120 22 ; 

    closedlg ; 

    if ( !exstatus ) endloop ; end 

    clb ; 
    loop root nnodes[0] 
	if ( !'choice[#2]' ) continue ; end 
	quote ----------------&10SUPPORTS (FROM EACH BLOCK) FOR GROUP NR. #2 ; 
	set ins $$ttag>( #2; 
	loop 1 nblocks 
	    set outs $$ins<,; 
	    set tmp $$ins>,; 
	    set ins $$tmp ; 
            if ( isinstring [ $outs ? ] ) quote Block #3: irrelevant ; 
            else 
               if ( isinstring [ $outs 0 ] ) quote Block #3: indifferent ; 
	       else 
	  	   if ( isinstring [ $outs + ] ) quote Block #3: support ($outs) ; 
                   else quote Block #3: CONTRADICT ($outs) ; end 
                   end 
		end 
	    stop 
	stop 

     if ( 'blonu' ) 
	loop root nnodes[0] 
                if ( ( #2 == root ) || ( anc [ 0 #2 ] == root ) ) ttag <#2 ; continue ; end 
		set ins $$ttag>( #2; 
		loop 1 'blonu' 
		    set outs $$ins<,; 
		    set tmp $$ins>,; 
		    set ins $$tmp ; 
		    stop 
		ttag < #2 ; 
		ttag +#2 $outs;
		stop 
        goto TAGGIT 'blonu' ; 
	ttag ; 
	ttag - ; 
	keep 0 ; 
	p taggedtre.out ; 
        setloop 1 ; 
	end 

    stop 

view :SUPPORTS; 
	
proc/; 

label TAGGIT ; 
quote *----------------
SUPPORTS (FOR EACH GROUP) FROM BLOCK NR. %1
(press ENTER to continue viewing, ESC to interrupt); 
proc/;